Before we get to all that, there's a couple things I want to fix with our last project. First, I noticed that a bullet won't fire if you click exactly on an enemy. This has to do with the fact that your mouse click isn't registering with the 'stage', it's registering with the 'enemy'. All that's needed to fix this is to set the 'mouseEnabled' property of our enemy class to false. All display objects have a mouse enabled property that can disallow any interactivity with a mouse click. Just put this code in the 'addEnemy' function after you create an enemy.

enemy.mouseEnabled = false

Next I realized that our bullet array could become very long, since objects that leave our screen are still being updated. We could eventually have hundreds of bullet objects flying off to who knows where, which could bog down our game. To solve this we need to check every bullet if it is still inbounds per frame, and if it isn't, delete it from our bullets array and from the display list. Change the bullet 'for' loop in our 'updateGame' function.

for( i = 0; i < _bullets.length; i++)
{
	_bullets[i].update();
				
	//We remove a bullet if its not inBounds.
	//We check this using our function below.
	if(!checkInBounds(_bullets[i]))
	{
		removeChild(_bullets[i]);
		_bullets.splice(i,1);
		i--;
	}
}

This should be pretty familiar, except that we still need to write our checkInBounds function.

//Note that this function takes any display object so we could call this using a Sprite or Enemy
//or any other displayObject.
//It also returns a boolean value (true/false) depending on whether the object is in bounds or not.

public function checkInBounds(obj:DisplayObject):Boolean
{
	//if the x or y value is less than 0 or greater than the stage,
	//return false to indicate the object is not inbounds.
	if(obj.x > stage.stageWidth ||
		obj.x < 0 ||
		obj.y > stage.stageHeight ||
		obj.y < 0)
		return false;
		
	//return true if we haven't returned false
	return true;
}

Now that that's done, we can move on to adding functionality to our game. First let's add a couple variables to hold our score and our number of lives. Add these to our variables at the top of our MyGame class.

private var _numLives:uint = 3;
private var _score:uint = 0;

All we really have to do now is increase the score every time we kill an enemy and decrease our lives when we die.

for(var i = 0; i < _enemies.length; i++)
{
	_enemies[i].update();
				
	if(_enemies[i].hitTestObject(_player))
	{
		//Decrease lives if enemy hits player
		numLives--;
		
		//We also exit our function if we run out of lives so nothing else gets checked
		if(numLives == 0)return;
					
		removeChild(_enemies[i]);
		_enemies.splice(i,1);
		i--;
		break;
	}
				
	for(var j = 0; j < _bullets.length; j++)
	{
		if(_enemies[i].hitTestObject(_bullets[j]))
		{
			//Increase score if bullet hits an enemy.
			score++;
						
			removeChild(_enemies[i]);
			_enemies.splice(i,1);
			removeChild(_bullets[j]);
			_bullets.splice(j,1);
					
			i--;
			j--;
			break;
		}
	}
}

This isn't going to work if we plug this in, because notice that I used variables called numScore and score instead of _numScore and _score. You may have been wondering why are variables generally have an underscore underneath them, and this is where we learn about getter and setter functions. I'll post the code and explain it after.

public function get score():uint
{
	return _score;
}

public function set score(score:uint)
{
	_score = score;
}

public function get numLives():uint
{
	return _numLives;
}

public function set numLives(lives:uint)
{
	_numLives = lives;
}

public function set numLives(lives:uint)
{
	_numLives = lives
	
	if(_numLives == 0)endGame();
}

//At the end of the game we remove all our bullets and enemies (We don't need to splice because we will be creating
//a completely new array anyway).  We also remove the player and our head, stop the timer, and remove all our event
//listeners.  We then call the init function with a value of false indicating that this is not our first game.
public function endGame()
{
	for(var i = 0; i < _bullets.length; i++)
	{
		removeChild(_bullets[i]);
	}
	for(i = 0; i < _enemies.length; i++)
	{
		removeChild(_enemies[i]);
	}
	removeChild(_player);
			
	_enemyTimer.stop();
	_enemyTimer.removeEventListener(TimerEvent.TIMER, addEnemy);
			
	stage.removeEventListener(MouseEvent.MOUSE_MOVE, rotatePlayer);
	stage.removeEventListener(Event.ENTER_FRAME, updateGame);
	stage.removeEventListener(MouseEvent.CLICK, fireBullet);
			
}

Next let's let the player see his score and number of lives with an on screen HUD. If we ever want text on the screen we need to use flash's TextField object. We'll need to import a couple of classes.

//allows us to use text fields
import flash.text.TextField;

//allows greater formatting of our text
import flash.text.TextFormat;

_hudText:TextField = new TextField();

public function setHudTextField()
{
	var tFormat:TextFormat = new TextFormat();
	tFormat.font = "Arial";
	tFormat.size = 20;
	tFormat.bold = true;
	tFormat.color = 0x000000;
			
	_hudText.defaultTextFormat = tFormat;	//Sets the text field information to read from our TextFormat above
	_hudText.width = 500;
	_hudText.selectable = false;		//allows text to be selectable by mouse
	addChild(_hudText);					//adds textfield to the display list like any other display object
}

We're going to do three things next, write a function that sets the text of our HUD, and change a couple setter functions so that our HUD will change based on the values of our score and lives.

//This is called every time the score or number of lives changes using the 
//set score and set numLives methods.

public function setHudText()
{
	//We convert our _score and _numLives values to strings using the toString() method
	_hudText.text = "Lives: " + _numLives.toString() + "		" +
					"Score: " + _score.toString();
}

public function set score(score:uint)
{
	_score = score;
			
	//The score changes so our hud must reflect that
	setHudText();
		
}
	
public function set numLives(lives:uint)
{
	_numLives = lives;
	
	setHudText();

	if(_numLives == 0)endGame();
}

The last thing I'm going to go through is making the game harder as we go. There's a few ways we could do this, but I decided the following rule: